Lorsqu’on gère un classeur Excel contenant plusieurs feuilles de données, on a tendance a créer une feuille spécifique servant de récapitulatif/tableau de bord. Dans son contenu, il est parfois utile d’afficher le nom des feuilles utilisées.
May 6 C’est possible vous propose 2 manières de procéder. Cet article sera consacré à la première méthode. Pour cela on va utiliser différentes fonctions d’Excel que l’on va combiner pour obtenir une formule de calcul utilisable.
Fonction CELLULE
Principe
La fonction CELLULE renvoie des informations sur la mise en forme, les références ou le contenu d’un emplacement du classeur Excel.
Syntaxe
CELLULE(type_info, [référence])
avec les arguments suivants :
- type_info : comme son nom l’indique, c’est le type d’information que vous recherchez. Argument obligatoire.
- référence : cellule/emplacement pour lequel vous voulez des informations. Argument facultatif
Mise en pratique
=CELLULE(nomfichier;Feuil2!$A$1)
Comme vous pouvez le voir, on obtient comme résultat le chemin absolu de la feuille sur votre appareil (l’emplacement du fichier + le nom de la feuille).
Nous voulons uniquement garder le nom de la feuille. On va donc utiliser d’autres fonctions d’Excel pour extraire ce que l’on veut.
Fonction NBCAR
Principe
La fonction NBCAR renvoie le nombre de caractères dans une chaîne de caractères.
Syntaxe
NBCAR(texte)
avec l’argument texte : désigne la chaîne de caractères. Argument obligatoire.
Mise en pratique
J’ai besoin de récupérer le nom de la feuille mais le problème est que je ne connais pas par avance le nombre de caractères de son nom.
Pour cela, je vais compter tout d’abord le nombre de caractères du chemin absolu.
Cela donne la formule de calcul :
=NBCAR(B1) ou =NBCAR(CELLULE("nomfichier";Feuil2!$A$1)) 
Il y a 70 caractères dans notre chemin absolu.
Mais combien y en a-t-il pour notre nom de feuille ?
Fonction TROUVE
Principe
La fonction TROUVE renvoie la position d’une chaîne de caractères à partir du début d’une seconde chaîne de caractères.
Syntaxe
TROUVE(texte_cherché, texte, [no_départ])
avec les arguments suivants :
- texte_cherché : Il s’agit du texte à trouver. Argument obligatoire.
- texte : Il s’agit du texte qui contient celui que vous recherchez. Argument obligatoire.
- no_départ : position du début de la recherche. Par défaut, il va commencer au premier caractère de l’argument texte.
Mise en pratique
Avez-vous remarqué que dans notre chemin absolu, avant le nom de la feuille, se trouve le nom du fichier entre crochet.
Donc, avant le nom de la feuille, il y aura toujours un crochet fermé. On va rechercher sa position.
on obtient :
=TROUVE("]";B1) ou =TROUVE("]";CELLULE("nomfichier";Feuil2!$B$1)) 
Le ] se trouve à la 64e position de notre chemin absolu.
On y est presque !
Fonction DROITE
Principe
La fonction DROITE renvoie le(s) dernier(s) caractère(s) d’une chaîne de texte.
Syntaxe
DROITE(texte,[no_car])
avec les arguments suivants :
- texte : Représente la chaîne de texte contenant les caractères à extraire. Argument obligatoire
- no_car : Indique le nombre de caractères à extraire. Argument facultatif.
Mise en pratique
On connait donc par déduction le nombre de caractères grâce aux fonctions NBCAR et TROUVE. Il s’agit de 6 (70e – 65e position).
On obtient la formule finale :
=DROITE(CELLULE("nomfichier";Feuil2!$B$1);NBCAR(CELLULE("nomfichier";Feuil2!$B$1))-TROUVE("]";CELLULE("nomfichier";Feuil2!$B$1))) 
